// TEXT FLOOD TurboIRC Script
// By Chourdakis Michael ,© 1998
// This script uses IntegerLists index 0 , 1 , 2

// This event can be loaded like 
// /_event TEXTFLOOD 21 2 0 +* PRIVMSG #* :*|||+* PRIVMSG &* :*|||+* PRIVMSG %* :*|||?.\demos\textflood.txt

// Formula for TextFlood 
// When a message is got , set the tick count in int[0]
// If old tick count is too slow , increase int[1]
// If int[1] comes to 3 , kick .

// Take Old User Tick Count

int OldZ = GetUserData($nick,0)

// Take current Tick Count
int NewZ = GetTickCount()

if (OldZ == 0)
 // No need to fire ... just add the timer
 /setuserdata $nick 0 %NewZ%
 return
endif

// Here , it is not too last ...!
int Diff = NewZ - OldZ

// Is difference too high ?
if (Diff > 6000)
 // yes , clear all 0 and 1 entries , flood control not exist
 /setuserdata $nick 0 0
 /setuserdata $nick 1 0
 //setuserdata $nick 2 0
 return
endif
// Now , it is too low ! Flood step 1 !!
// Increase int[1] and If it is set to 3 , show first warning
int OldF = GetUserData($nick,1)
if (OldF < 2)
 OldF += 1
 /setuserdata $nick 1 %OldF%
 return
endif

// Here ? The flood steps are 3 ! , throw warning or KICK !
int OldW = GetUserData($nick,2)
if (OldW < 3)
 OldW += 1
 /setuserdata $nick 0 0
 /setuserdata $nick 2 %OldW%
 /display $channel $nick , 4Warning #%OldW%1 : Flood protection is ENABLED !!
 return
endif

// Here , KICK him
/setuserdata $nick 0 0
/setuserdata $nick 1 0
/setuserdata $nick 2 0
/kick $channel $nick  DirtY FloodER !!